// *****************************************************************************
// * Config_SIOC ver 3.7B1   -     By Manolo Vélez    -    www.opencockpits.com
// *****************************************************************************
// * FileName : XPDER IVAP VALORES.txt
// * Date : 24/02/2010



Var 0000, Value 0
{
  &D_ACTIVE = 1200    
  &DIG_POS_STATUS = 1    
  &DIS_ATC = 1    
}

Var 0010, name FS_XPDER_ID, Link FSUIPC_INOUT, Offset $0354, Length 2

Var 0015, name IVAP_SB_MODE, Link FSUIPC_INOUT, Offset $7B91, Length 1

Var 0020, name IVAP_SB_IDENT, Link FSUIPC_INOUT, Offset $7B93, Length 1

Var 0025, name XPDER_FAIL, Link FSUIPC_INOUT, Offset $0B6F, Length 1
{
  IF &XPDER_FAIL = 1
  {
    &D_FAIL = -999997    
    &LED_FAIL = 1    
  }
  ELSE
  {
    &D_FAIL = -999999    
    &LED_FAIL = 0    
  }
}

Var 0030, name TCAS_MAGENTA, Link FSUIPC_INOUT, Offset $04F4, Length 2

Var 0002, name DIG_POS_STATUS

Var 0050, name DIG_1_SUB, Value 0
{
  CALL &DIGITS_SUB
}

Var 0051, name DIG_2_SUB, Value 0
{
  CALL &DIGITS_SUB
}

Var 0052, name DIG_3_SUB, Value 2
{
  CALL &DIGITS_SUB
}

Var 0053, name DIG_4_SUB, Value 1
{
  CALL &DIGITS_SUB
}

Var 0100, name D_ACTIVE, Link IOCARD_DISPLAY, Device 1, Digit 0, Numbers 4

Var 0102, name D_FAIL, Link IOCARD_DISPLAY, Device 1, Digit 4, Numbers 1

Var 0104, name D_BRIGHT, Link IOCARD_DISPLAY, Device 1, Digit 16, Numbers 3

Var 0200, name DIS_ATC, Link IOCARD_OUT, Device 1, Output 20

Var 0202, name DIS_1, Link IOCARD_OUT, Device 1, Output 21

Var 0204, name DIS_2, Link IOCARD_OUT, Device 1, Output 22

Var 0206, name LED_FAIL, Link IOCARD_OUT, Device 1, Output 23

Var 0302, name E_LEFT, Link IOCARD_ENCODER, Device 1, Input 5, Aceleration 1, Type 2
{
  L0 = &E_LEFT * 1
  &DIG_POS_STATUS = ROTATE 1 ,4 ,L0
}

Var 0300, name E_RIGHT, Link IOCARD_ENCODER, Device 1, Input 10, Aceleration 1, Type 2
{
  IF &DIG_POS_STATUS = 1
  {
    L0 = &E_RIGHT * -1
    &DIG_1_SUB = ROTATE 0 ,7 ,L0
  }
  IF &DIG_POS_STATUS = 2
  {
    L0 = &E_RIGHT * -1
    &DIG_2_SUB = ROTATE 0 ,7 ,L0
  }
  IF &DIG_POS_STATUS = 3
  {
    L0 = &E_RIGHT * -1
    &DIG_3_SUB = ROTATE 0 ,7 ,L0
  }
  IF &DIG_POS_STATUS = 4
  {
    L0 = &E_RIGHT * -1
    &DIG_4_SUB = ROTATE 0 ,7 ,L0
  }
}

Var 0400, name I_IDENT, Link IOCARD_SW, Device 1, Input 12
{
  IF &I_IDENT = 1
  {
    &IVAP_SB_IDENT = 1    
  }
}

Var 0404, name I_XPNDR, Link IOCARD_SW, Device 1, Input 7
{
  IF &I_XPNDR = 1
  {
    &DIS_1 = 0    
    &DIS_2 = 1    
  }
  ELSE
  {
    &DIS_1 = 1    
    &DIS_2 = 0    
  }
}

Var 0406, name STANDBY, Link IOCARD_SW, Device 1, Input 0
{
  IF &STANDBY = 1
  {
    &IVAP_SB_MODE = 1    
  }
}

Var 0408, name I_R_ALT, Link IOCARD_SW, Device 1, Input 1

Var 0410, name I_R_XPN, Link IOCARD_SW, Device 1, Input 2
{
  IF &I_R_XPN = 1
  {
    &IVAP_SB_MODE = 0    
  }
}

Var 0412, name I_R_TAO, Link IOCARD_SW, Device 1, Input 3
{
  IF &I_R_TAO = 1
  {
    &TCAS_MAGENTA = 51    
  }
}

Var 0414, name I_R_TAR, Link IOCARD_SW, Device 1, Input 4
{
  IF &I_R_TAR = 1
  {
    &TCAS_MAGENTA = 51    
  }
}

Var 0999, name DIGITS_SUB, Link SUBRUTINE
{
  L0 = &DIG_4_SUB * 1000
  L1 = &DIG_3_SUB * 100
  L0 = L0 + L1
  L1 = &DIG_2_SUB * 10
  L0 = L0 + L1
  L0 = L0 + &DIG_1_SUB
  &D_ACTIVE = L0    
  &FS_XPDER_ID = TOBCD &D_ACTIVE
}